API Excel Zugriff mit Windows (via Daten abrufen)

Prinzipiell gibt es für Windows Benutzer zwei Varianten um per Excel auf die helloHQ-API zuzugreifen:

Zugriff über die Excel Funktion Daten abrufen
Zugriff per Excel Add-In

Um die Daten direkt über Excel abzurufen musst du auf den Reiter "Daten" - "Daten abrufen" - "Aus anderen Quellen" - "Leere Abfrage" gehen.

Screen 1

Nun erscheint ein Fenster auf dem zu auf "Erweiterter Editor" klickst.

Screen 2

In nächsten Fenster muss die folgende Abfragen eingegeben werden (Einfach per Copy & Paste einfügen):

let 
    BaseUrl         = "https://api.hellohq.io/v1/<<<HIER OBJEKT EINFÜGEN>>>?",
    Token           = "<<<HIER API TOKEN EINFÜGEN>>>",
    EntitiesPerPage = 1000,
 
    GetJson = (Url) =>
        let Options = [Headers=[ #"Authorization" = "Bearer " & Token ]],
            RawData = Web.Contents(Url, Options),
            Json    = Json.Document(RawData)
        in  Json,
 
    GetEntityCount = () =>
        let Url   = BaseUrl & "$count=true&$top=0",
            Json  = GetJson(Url),
            Count = Json[#"@odata.count"]
        in  Count,
 
    GetPage = (Index) =>
        let Skip  = "$skip=" & Text.From(Index * EntitiesPerPage),
            Top   = "$top=" & Text.From(EntitiesPerPage),
            Url   = BaseUrl & Skip & "&" & Top,
            Json  = GetJson(Url),
            Value = Json[#"value"]
        in  Value,
 
    EntityCount = List.Max({ EntitiesPerPage, GetEntityCount() }),
    PageCount   = Number.RoundUp(EntityCount / EntitiesPerPage),
    PageIndices = { 0 .. PageCount - 1 },
    Pages       = List.Transform(PageIndices, each GetPage(_)),
    Entities    = List.Union(Pages),
    Table       = Table.FromList(Entities, Splitter.SplitByNothing(), null, null, ExtraValues.Error)
in
    Table

Achtung: Wenn mehrere Elemente Abgefragt werden sollen, kann der Inhalt der BaseUrl wie folgt angepasst werden (Beispielabfrage): "https://api.hqlabs.de/v1/UserReportings?$expand=Project,User,Task&",

Nun sind noch 2 kleine Anpassungen notwendig. Erstens, musst du dich authentifizieren. Dies passiert über den “API Token”, den du dir direkt aus helloHQ holen kannst. Unter Admin/ API Clients ist dieser Token zu finden, der nun in unser Skript statt <<<HIER API TOKEN EINFÜGEN>>> einsetzen, eingefügt wird.

Nun musst du der API noch sagen, welche Objekte eigentlich abgerufen werden sollen (z.B. Leads, Unternehmen, Projekte usw.). Das gewünschte Objekt fügst du dann in den Code anstelle von <<<HIER OBJEKT EINFÜGEN>>> ein. Die Liste aller verfügbaren Objekte findest du unter https://developer.helloHQ.io

Screen 3

Wenn Du nun auf "Fertig" klickst musst Du noch die Spalten erweitern.

Screen 4

Anschließend kann die Abfrage benannt werden und per "Schließen & laden" die Daten in die Excel übernommen werden.

Screen 5

Über den Reiter "Daten" - "Alle aktualisieren" können ab jetzt immer die aktuellen Daten aus dem HQ abgerufen werden.

Screen 6

Nun kannst Du mit den Daten in Excel weiterarbeiten und z.B. Pivot-Tabellen und Grafiken zur Auswertung erstellen. Natürlich kannst du hierfür auch mehrere Abfragen pro Excel hinzufügen, z.B. um Projekte und Unternehmen zu verbinden.

ACHTUNG: Wenn du eine ältere Version von Excel als 2016 verwendest musst du das kostenlose Excel Add-In PowerQuery von Microsoft installieren.